home *** CD-ROM | disk | FTP | other *** search
/ Personal Computer World 2009 February / PCWFEB09.iso / Software / Linux / Kubuntu 8.10 / kubuntu-8.10-desktop-i386.iso / casper / filesystem.squashfs / usr / bin / h2xs < prev    next >
Text File  |  2008-07-24  |  60KB  |  2,180 lines
  1. #!/usr/bin/perl
  2.     eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
  3.     if $running_under_some_shell;
  4.  
  5. use warnings;
  6.  
  7. =head1 NAME
  8.  
  9. h2xs - convert .h C header files to Perl extensions
  10.  
  11. =head1 SYNOPSIS
  12.  
  13. B<h2xs> [B<OPTIONS> ...] [headerfile ... [extra_libraries]]
  14.  
  15. B<h2xs> B<-h>|B<-?>|B<--help>
  16.  
  17. =head1 DESCRIPTION
  18.  
  19. I<h2xs> builds a Perl extension from C header files.  The extension
  20. will include functions which can be used to retrieve the value of any
  21. #define statement which was in the C header files.
  22.  
  23. The I<module_name> will be used for the name of the extension.  If
  24. module_name is not supplied then the name of the first header file
  25. will be used, with the first character capitalized.
  26.  
  27. If the extension might need extra libraries, they should be included
  28. here.  The extension Makefile.PL will take care of checking whether
  29. the libraries actually exist and how they should be loaded.  The extra
  30. libraries should be specified in the form -lm -lposix, etc, just as on
  31. the cc command line.  By default, the Makefile.PL will search through
  32. the library path determined by Configure.  That path can be augmented
  33. by including arguments of the form B<-L/another/library/path> in the
  34. extra-libraries argument.
  35.  
  36. In spite of its name, I<h2xs> may also be used to create a skeleton pure
  37. Perl module. See the B<-X> option.
  38.  
  39. =head1 OPTIONS
  40.  
  41. =over 5
  42.  
  43. =item B<-A>, B<--omit-autoload>
  44.  
  45. Omit all autoload facilities.  This is the same as B<-c> but also
  46. removes the S<C<use AutoLoader>> statement from the .pm file.
  47.  
  48. =item B<-B>, B<--beta-version>
  49.  
  50. Use an alpha/beta style version number.  Causes version number to
  51. be "0.00_01" unless B<-v> is specified.
  52.  
  53. =item B<-C>, B<--omit-changes>
  54.  
  55. Omits creation of the F<Changes> file, and adds a HISTORY section to
  56. the POD template.
  57.  
  58. =item B<-F>, B<--cpp-flags>=I<addflags>
  59.  
  60. Additional flags to specify to C preprocessor when scanning header for
  61. function declarations.  Writes these options in the generated F<Makefile.PL>
  62. too.
  63.  
  64. =item B<-M>, B<--func-mask>=I<regular expression>
  65.  
  66. selects functions/macros to process.
  67.  
  68. =item B<-O>, B<--overwrite-ok>
  69.  
  70. Allows a pre-existing extension directory to be overwritten.
  71.  
  72. =item B<-P>, B<--omit-pod>
  73.  
  74. Omit the autogenerated stub POD section.
  75.  
  76. =item B<-X>, B<--omit-XS>
  77.  
  78. Omit the XS portion. Used to generate a skeleton pure Perl module.
  79. C<-c> and C<-f> are implicitly enabled.
  80.  
  81. =item B<-a>, B<--gen-accessors>
  82.  
  83. Generate an accessor method for each element of structs and unions. The
  84. generated methods are named after the element name; will return the current
  85. value of the element if called without additional arguments; and will set
  86. the element to the supplied value (and return the new value) if called with
  87. an additional argument. Embedded structures and unions are returned as a
  88. pointer rather than the complete structure, to facilitate chained calls.
  89.  
  90. These methods all apply to the Ptr type for the structure; additionally
  91. two methods are constructed for the structure type itself, C<_to_ptr>
  92. which returns a Ptr type pointing to the same structure, and a C<new>
  93. method to construct and return a new structure, initialised to zeroes.
  94.  
  95. =item B<-b>, B<--compat-version>=I<version>
  96.  
  97. Generates a .pm file which is backwards compatible with the specified
  98. perl version.
  99.  
  100. For versions < 5.6.0, the changes are.
  101.     - no use of 'our' (uses 'use vars' instead)
  102.     - no 'use warnings'
  103.  
  104. Specifying a compatibility version higher than the version of perl you
  105. are using to run h2xs will have no effect.  If unspecified h2xs will default
  106. to compatibility with the version of perl you are using to run h2xs.
  107.  
  108. =item B<-c>, B<--omit-constant>
  109.  
  110. Omit C<constant()> from the .xs file and corresponding specialised
  111. C<AUTOLOAD> from the .pm file.
  112.  
  113. =item B<-d>, B<--debugging>
  114.  
  115. Turn on debugging messages.
  116.  
  117. =item B<-e>, B<--omit-enums>=[I<regular expression>]
  118.  
  119. If I<regular expression> is not given, skip all constants that are defined in
  120. a C enumeration. Otherwise skip only those constants that are defined in an
  121. enum whose name matches I<regular expression>.
  122.  
  123. Since I<regular expression> is optional, make sure that this switch is followed
  124. by at least one other switch if you omit I<regular expression> and have some
  125. pending arguments such as header-file names. This is ok:
  126.  
  127.     h2xs -e -n Module::Foo foo.h
  128.  
  129. This is not ok:
  130.  
  131.     h2xs -n Module::Foo -e foo.h
  132.  
  133. In the latter, foo.h is taken as I<regular expression>.
  134.  
  135. =item B<-f>, B<--force>
  136.  
  137. Allows an extension to be created for a header even if that header is
  138. not found in standard include directories.
  139.  
  140. =item B<-g>, B<--global>
  141.  
  142. Include code for safely storing static data in the .xs file.
  143. Extensions that do no make use of static data can ignore this option.
  144.  
  145. =item B<-h>, B<-?>, B<--help>
  146.  
  147. Print the usage, help and version for this h2xs and exit.
  148.  
  149. =item B<-k>, B<--omit-const-func>
  150.  
  151. For function arguments declared as C<const>, omit the const attribute in the
  152. generated XS code.
  153.  
  154. =item B<-m>, B<--gen-tied-var>
  155.  
  156. B<Experimental>: for each variable declared in the header file(s), declare
  157. a perl variable of the same name magically tied to the C variable.
  158.  
  159. =item B<-n>, B<--name>=I<module_name>
  160.  
  161. Specifies a name to be used for the extension, e.g., S<-n RPC::DCE>
  162.  
  163. =item B<-o>, B<--opaque-re>=I<regular expression>
  164.  
  165. Use "opaque" data type for the C types matched by the regular
  166. expression, even if these types are C<typedef>-equivalent to types
  167. from typemaps.  Should not be used without B<-x>.
  168.  
  169. This may be useful since, say, types which are C<typedef>-equivalent
  170. to integers may represent OS-related handles, and one may want to work
  171. with these handles in OO-way, as in C<$handle-E<gt>do_something()>.
  172. Use C<-o .> if you want to handle all the C<typedef>ed types as opaque
  173. types.
  174.  
  175. The type-to-match is whitewashed (except for commas, which have no
  176. whitespace before them, and multiple C<*> which have no whitespace
  177. between them).
  178.  
  179. =item B<-p>, B<--remove-prefix>=I<prefix>
  180.  
  181. Specify a prefix which should be removed from the Perl function names,
  182. e.g., S<-p sec_rgy_> This sets up the XS B<PREFIX> keyword and removes
  183. the prefix from functions that are autoloaded via the C<constant()>
  184. mechanism.
  185.  
  186. =item B<-s>, B<--const-subs>=I<sub1,sub2>
  187.  
  188. Create a perl subroutine for the specified macros rather than autoload
  189. with the constant() subroutine.  These macros are assumed to have a
  190. return type of B<char *>, e.g.,
  191. S<-s sec_rgy_wildcard_name,sec_rgy_wildcard_sid>.
  192.  
  193. =item B<-t>, B<--default-type>=I<type>
  194.  
  195. Specify the internal type that the constant() mechanism uses for macros.
  196. The default is IV (signed integer).  Currently all macros found during the
  197. header scanning process will be assumed to have this type.  Future versions
  198. of C<h2xs> may gain the ability to make educated guesses.
  199.  
  200. =item B<--use-new-tests>
  201.  
  202. When B<--compat-version> (B<-b>) is present the generated tests will use
  203. C<Test::More> rather than C<Test> which is the default for versions before
  204. 5.7.2 .   C<Test::More> will be added to PREREQ_PM in the generated
  205. C<Makefile.PL>.
  206.  
  207. =item B<--use-old-tests>
  208.  
  209. Will force the generation of test code that uses the older C<Test> module.
  210.  
  211. =item B<--skip-exporter>
  212.  
  213. Do not use C<Exporter> and/or export any symbol.
  214.  
  215. =item B<--skip-ppport>
  216.  
  217. Do not use C<Devel::PPPort>: no portability to older version.
  218.  
  219. =item B<--skip-autoloader>
  220.  
  221. Do not use the module C<AutoLoader>; but keep the constant() function
  222. and C<sub AUTOLOAD> for constants.
  223.  
  224. =item B<--skip-strict>
  225.  
  226. Do not use the pragma C<strict>.
  227.  
  228. =item B<--skip-warnings>
  229.  
  230. Do not use the pragma C<warnings>.
  231.  
  232. =item B<-v>, B<--version>=I<version>
  233.  
  234. Specify a version number for this extension.  This version number is added
  235. to the templates.  The default is 0.01, or 0.00_01 if C<-B> is specified.
  236. The version specified should be numeric.
  237.  
  238. =item B<-x>, B<--autogen-xsubs>
  239.  
  240. Automatically generate XSUBs basing on function declarations in the
  241. header file.  The package C<C::Scan> should be installed. If this
  242. option is specified, the name of the header file may look like
  243. C<NAME1,NAME2>. In this case NAME1 is used instead of the specified
  244. string, but XSUBs are emitted only for the declarations included from
  245. file NAME2.
  246.  
  247. Note that some types of arguments/return-values for functions may
  248. result in XSUB-declarations/typemap-entries which need
  249. hand-editing. Such may be objects which cannot be converted from/to a
  250. pointer (like C<long long>), pointers to functions, or arrays.  See
  251. also the section on L<LIMITATIONS of B<-x>>.
  252.  
  253. =back
  254.  
  255. =head1 EXAMPLES
  256.  
  257.  
  258.     # Default behavior, extension is Rusers
  259.     h2xs rpcsvc/rusers
  260.  
  261.     # Same, but extension is RUSERS
  262.     h2xs -n RUSERS rpcsvc/rusers
  263.  
  264.     # Extension is rpcsvc::rusers. Still finds <rpcsvc/rusers.h>
  265.     h2xs rpcsvc::rusers
  266.  
  267.     # Extension is ONC::RPC.  Still finds <rpcsvc/rusers.h>
  268.     h2xs -n ONC::RPC rpcsvc/rusers
  269.  
  270.     # Without constant() or AUTOLOAD
  271.     h2xs -c rpcsvc/rusers
  272.  
  273.     # Creates templates for an extension named RPC
  274.     h2xs -cfn RPC
  275.  
  276.     # Extension is ONC::RPC.
  277.     h2xs -cfn ONC::RPC
  278.  
  279.     # Extension is a pure Perl module with no XS code.
  280.     h2xs -X My::Module
  281.  
  282.     # Extension is Lib::Foo which works at least with Perl5.005_03.
  283.     # Constants are created for all #defines and enums h2xs can find
  284.     # in foo.h.
  285.     h2xs -b 5.5.3 -n Lib::Foo foo.h
  286.  
  287.     # Extension is Lib::Foo which works at least with Perl5.005_03.
  288.     # Constants are created for all #defines but only for enums
  289.     # whose names do not start with 'bar_'.
  290.     h2xs -b 5.5.3 -e '^bar_' -n Lib::Foo foo.h
  291.  
  292.     # Makefile.PL will look for library -lrpc in
  293.     # additional directory /opt/net/lib
  294.     h2xs rpcsvc/rusers -L/opt/net/lib -lrpc
  295.  
  296.     # Extension is DCE::rgynbase
  297.     # prefix "sec_rgy_" is dropped from perl function names
  298.     h2xs -n DCE::rgynbase -p sec_rgy_ dce/rgynbase
  299.  
  300.     # Extension is DCE::rgynbase
  301.     # prefix "sec_rgy_" is dropped from perl function names
  302.     # subroutines are created for sec_rgy_wildcard_name and
  303.     # sec_rgy_wildcard_sid
  304.     h2xs -n DCE::rgynbase -p sec_rgy_ \
  305.     -s sec_rgy_wildcard_name,sec_rgy_wildcard_sid dce/rgynbase
  306.  
  307.     # Make XS without defines in perl.h, but with function declarations
  308.     # visible from perl.h. Name of the extension is perl1.
  309.     # When scanning perl.h, define -DEXT=extern -DdEXT= -DINIT(x)=
  310.     # Extra backslashes below because the string is passed to shell.
  311.     # Note that a directory with perl header files would
  312.     #  be added automatically to include path.
  313.     h2xs -xAn perl1 -F "-DEXT=extern -DdEXT= -DINIT\(x\)=" perl.h
  314.  
  315.     # Same with function declaration in proto.h as visible from perl.h.
  316.     h2xs -xAn perl2 perl.h,proto.h
  317.  
  318.     # Same but select only functions which match /^av_/
  319.     h2xs -M '^av_' -xAn perl2 perl.h,proto.h
  320.  
  321.     # Same but treat SV* etc as "opaque" types
  322.     h2xs -o '^[S]V \*$' -M '^av_' -xAn perl2 perl.h,proto.h
  323.  
  324. =head2 Extension based on F<.h> and F<.c> files
  325.  
  326. Suppose that you have some C files implementing some functionality,
  327. and the corresponding header files.  How to create an extension which
  328. makes this functionality accessible in Perl?  The example below
  329. assumes that the header files are F<interface_simple.h> and
  330. I<interface_hairy.h>, and you want the perl module be named as
  331. C<Ext::Ension>.  If you need some preprocessor directives and/or
  332. linking with external libraries, see the flags C<-F>, C<-L> and C<-l>
  333. in L<"OPTIONS">.
  334.  
  335. =over
  336.  
  337. =item Find the directory name
  338.  
  339. Start with a dummy run of h2xs:
  340.  
  341.   h2xs -Afn Ext::Ension
  342.  
  343. The only purpose of this step is to create the needed directories, and
  344. let you know the names of these directories.  From the output you can
  345. see that the directory for the extension is F<Ext/Ension>.
  346.  
  347. =item Copy C files
  348.  
  349. Copy your header files and C files to this directory F<Ext/Ension>.
  350.  
  351. =item Create the extension
  352.  
  353. Run h2xs, overwriting older autogenerated files:
  354.  
  355.   h2xs -Oxan Ext::Ension interface_simple.h interface_hairy.h
  356.  
  357. h2xs looks for header files I<after> changing to the extension
  358. directory, so it will find your header files OK.
  359.  
  360. =item Archive and test
  361.  
  362. As usual, run
  363.  
  364.   cd Ext/Ension
  365.   perl Makefile.PL
  366.   make dist
  367.   make
  368.   make test
  369.  
  370. =item Hints
  371.  
  372. It is important to do C<make dist> as early as possible.  This way you
  373. can easily merge(1) your changes to autogenerated files if you decide
  374. to edit your C<.h> files and rerun h2xs.
  375.  
  376. Do not forget to edit the documentation in the generated F<.pm> file.
  377.  
  378. Consider the autogenerated files as skeletons only, you may invent
  379. better interfaces than what h2xs could guess.
  380.  
  381. Consider this section as a guideline only, some other options of h2xs
  382. may better suit your needs.
  383.  
  384. =back
  385.  
  386. =head1 ENVIRONMENT
  387.  
  388. No environment variables are used.
  389.  
  390. =head1 AUTHOR
  391.  
  392. Larry Wall and others
  393.  
  394. =head1 SEE ALSO
  395.  
  396. L<perl>, L<perlxstut>, L<ExtUtils::MakeMaker>, and L<AutoLoader>.
  397.  
  398. =head1 DIAGNOSTICS
  399.  
  400. The usual warnings if it cannot read or write the files involved.
  401.  
  402. =head1 LIMITATIONS of B<-x>
  403.  
  404. F<h2xs> would not distinguish whether an argument to a C function
  405. which is of the form, say, C<int *>, is an input, output, or
  406. input/output parameter.  In particular, argument declarations of the
  407. form
  408.  
  409.     int
  410.     foo(n)
  411.     int *n
  412.  
  413. should be better rewritten as
  414.  
  415.     int
  416.     foo(n)
  417.     int &n
  418.  
  419. if C<n> is an input parameter.
  420.  
  421. Additionally, F<h2xs> has no facilities to intuit that a function
  422.  
  423.    int
  424.    foo(addr,l)
  425.     char *addr
  426.     int   l
  427.  
  428. takes a pair of address and length of data at this address, so it is better
  429. to rewrite this function as
  430.  
  431.     int
  432.     foo(sv)
  433.         SV *addr
  434.     PREINIT:
  435.         STRLEN len;
  436.         char *s;
  437.     CODE:
  438.         s = SvPV(sv,len);
  439.         RETVAL = foo(s, len);
  440.     OUTPUT:
  441.         RETVAL
  442.  
  443. or alternately
  444.  
  445.     static int
  446.     my_foo(SV *sv)
  447.     {
  448.     STRLEN len;
  449.     char *s = SvPV(sv,len);
  450.  
  451.     return foo(s, len);
  452.     }
  453.  
  454.     MODULE = foo    PACKAGE = foo    PREFIX = my_
  455.  
  456.     int
  457.     foo(sv)
  458.     SV *sv
  459.  
  460. See L<perlxs> and L<perlxstut> for additional details.
  461.  
  462. =cut
  463.  
  464. # ' # Grr
  465. use strict;
  466.  
  467.  
  468. my( $H2XS_VERSION ) = ' $Revision: 1.23 $ ' =~ /\$Revision:\s+([^\s]+)/;
  469. my $TEMPLATE_VERSION = '0.01';
  470. my @ARGS = @ARGV;
  471. my $compat_version = $];
  472.  
  473. use Getopt::Long;
  474. use Config;
  475. use Text::Wrap;
  476. $Text::Wrap::huge = 'overflow';
  477. $Text::Wrap::columns = 80;
  478. use ExtUtils::Constant qw (WriteConstants WriteMakefileSnippet autoload);
  479. use File::Compare;
  480. use File::Path;
  481.  
  482. sub usage {
  483.     warn "@_\n" if @_;
  484.     die <<EOFUSAGE;
  485. h2xs [OPTIONS ... ] [headerfile [extra_libraries]]
  486. version: $H2XS_VERSION
  487. OPTIONS:
  488.     -A, --omit-autoload   Omit all autoloading facilities (implies -c).
  489.     -B, --beta-version    Use beta \$VERSION of 0.00_01 (ignored if -v).
  490.     -C, --omit-changes    Omit creating the Changes file, add HISTORY heading
  491.                           to stub POD.
  492.     -F, --cpp-flags       Additional flags for C preprocessor/compile.
  493.     -M, --func-mask       Mask to select C functions/macros
  494.                           (default is select all).
  495.     -O, --overwrite-ok    Allow overwriting of a pre-existing extension directory.
  496.     -P, --omit-pod        Omit the stub POD section.
  497.     -X, --omit-XS         Omit the XS portion (implies both -c and -f).
  498.     -a, --gen-accessors   Generate get/set accessors for struct and union members
  499.                           (used with -x).
  500.     -b, --compat-version  Specify a perl version to be backwards compatibile with.
  501.     -c, --omit-constant   Omit the constant() function and specialised AUTOLOAD
  502.                           from the XS file.
  503.     -d, --debugging       Turn on debugging messages.
  504.     -e, --omit-enums      Omit constants from enums in the constant() function.
  505.                           If a pattern is given, only the matching enums are
  506.                           ignored.
  507.     -f, --force           Force creation of the extension even if the C header
  508.                           does not exist.
  509.     -g, --global          Include code for safely storing static data in the .xs file.
  510.     -h, -?, --help        Display this help message.
  511.     -k, --omit-const-func Omit 'const' attribute on function arguments
  512.                           (used with -x).
  513.     -m, --gen-tied-var    Generate tied variables for access to declared
  514.                           variables.
  515.     -n, --name            Specify a name to use for the extension (recommended).
  516.     -o, --opaque-re       Regular expression for \"opaque\" types.
  517.     -p, --remove-prefix   Specify a prefix which should be removed from the
  518.                           Perl function names.
  519.     -s, --const-subs      Create subroutines for specified macros.
  520.     -t, --default-type    Default type for autoloaded constants (default is IV).
  521.         --use-new-tests   Use Test::More in backward compatible modules.
  522.         --use-old-tests   Use the module Test rather than Test::More.
  523.         --skip-exporter   Do not export symbols.
  524.         --skip-ppport     Do not use portability layer.
  525.         --skip-autoloader Do not use the module C<AutoLoader>.
  526.         --skip-strict     Do not use the pragma C<strict>.
  527.         --skip-warnings   Do not use the pragma C<warnings>.
  528.     -v, --version         Specify a version number for this extension.
  529.     -x, --autogen-xsubs   Autogenerate XSUBs using C::Scan.
  530.         --use-xsloader    Use XSLoader in backward compatible modules (ignored
  531.                           when used with -X).
  532.  
  533. extra_libraries
  534.          are any libraries that might be needed for loading the
  535.          extension, e.g. -lm would try to link in the math library.
  536. EOFUSAGE
  537. }
  538.  
  539. my ($opt_A,
  540.     $opt_B,
  541.     $opt_C,
  542.     $opt_F,
  543.     $opt_M,
  544.     $opt_O,
  545.     $opt_P,
  546.     $opt_X,
  547.     $opt_a,
  548.     $opt_c,
  549.     $opt_d,
  550.     $opt_e,
  551.     $opt_f,
  552.     $opt_g,
  553.     $opt_h,
  554.     $opt_k,
  555.     $opt_m,
  556.     $opt_n,
  557.     $opt_o,
  558.     $opt_p,
  559.     $opt_s,
  560.     $opt_v,
  561.     $opt_x,
  562.     $opt_b,
  563.     $opt_t,
  564.     $new_test,
  565.     $old_test,
  566.     $skip_exporter,
  567.     $skip_ppport,
  568.     $skip_autoloader,
  569.     $skip_strict,
  570.     $skip_warnings,
  571.     $use_xsloader
  572.    );
  573.  
  574. Getopt::Long::Configure('bundling');
  575. Getopt::Long::Configure('pass_through');
  576.  
  577. my %options = (
  578.                 'omit-autoload|A'    => \$opt_A,
  579.                 'beta-version|B'     => \$opt_B,
  580.                 'omit-changes|C'     => \$opt_C,
  581.                 'cpp-flags|F=s'      => \$opt_F,
  582.                 'func-mask|M=s'      => \$opt_M,
  583.                 'overwrite_ok|O'     => \$opt_O,
  584.                 'omit-pod|P'         => \$opt_P,
  585.                 'omit-XS|X'          => \$opt_X,
  586.                 'gen-accessors|a'    => \$opt_a,
  587.                 'compat-version|b=s' => \$opt_b,
  588.                 'omit-constant|c'    => \$opt_c,
  589.                 'debugging|d'        => \$opt_d,
  590.                 'omit-enums|e:s'     => \$opt_e,
  591.                 'force|f'            => \$opt_f,
  592.                 'global|g'           => \$opt_g,
  593.                 'help|h|?'           => \$opt_h,
  594.                 'omit-const-func|k'  => \$opt_k,
  595.                 'gen-tied-var|m'     => \$opt_m,
  596.                 'name|n=s'           => \$opt_n,
  597.                 'opaque-re|o=s'      => \$opt_o,
  598.                 'remove-prefix|p=s'  => \$opt_p,
  599.                 'const-subs|s=s'     => \$opt_s,
  600.                 'default-type|t=s'   => \$opt_t,
  601.                 'version|v=s'        => \$opt_v,
  602.                 'autogen-xsubs|x'    => \$opt_x,
  603.                 'use-new-tests'      => \$new_test,
  604.                 'use-old-tests'      => \$old_test,
  605.                 'skip-exporter'      => \$skip_exporter,
  606.                 'skip-ppport'        => \$skip_ppport,
  607.                 'skip-autoloader'    => \$skip_autoloader,
  608.                 'skip-warnings'      => \$skip_warnings,
  609.                 'skip-strict'        => \$skip_strict,
  610.                 'use-xsloader'       => \$use_xsloader,
  611.               );
  612.  
  613. GetOptions(%options) || usage;
  614.  
  615. usage if $opt_h;
  616.  
  617. if( $opt_b ){
  618.     usage "You cannot use -b and -m at the same time.\n" if ($opt_b && $opt_m);
  619.     $opt_b =~ /^v?(\d+)\.(\d+)\.(\d+)/ ||
  620.     usage "You must provide the backwards compatibility version in X.Y.Z form. "
  621.           .  "(i.e. 5.5.0)\n";
  622.     my ($maj,$min,$sub) = ($1,$2,$3);
  623.     if ($maj < 5 || ($maj == 5 && $min < 6)) {
  624.         $compat_version =
  625.         $sub ? sprintf("%d.%03d%02d",$maj,$min,$sub) :
  626.                sprintf("%d.%03d",    $maj,$min);
  627.     } else {
  628.         $compat_version = sprintf("%d.%03d%03d",$maj,$min,$sub);
  629.     }
  630. } else {
  631.     my ($maj,$min,$sub) = $compat_version =~ /(\d+)\.(\d\d\d)(\d*)/;
  632.     $sub ||= 0;
  633.     warn sprintf <<'EOF', $maj,$min,$sub;
  634. Defaulting to backwards compatibility with perl %d.%d.%d
  635. If you intend this module to be compatible with earlier perl versions, please
  636. specify a minimum perl version with the -b option.
  637.  
  638. EOF
  639. }
  640.  
  641. if( $opt_B ){
  642.     $TEMPLATE_VERSION = '0.00_01';
  643. }
  644.  
  645. if( $opt_v ){
  646.     $TEMPLATE_VERSION = $opt_v;
  647.  
  648.     # check if it is numeric
  649.     my $temp_version = $TEMPLATE_VERSION;
  650.     my $beta_version = $temp_version =~ s/(\d)_(\d\d)/$1$2/;
  651.     my $notnum;
  652.     {
  653.         local $SIG{__WARN__} = sub { $notnum = 1 };
  654.         use warnings 'numeric';
  655.         $temp_version = 0+$temp_version;
  656.     }
  657.  
  658.     if ($notnum) {
  659.         my $module = $opt_n || 'Your::Module';
  660.         warn <<"EOF";
  661. You have specified a non-numeric version.  Unless you supply an
  662. appropriate VERSION class method, users may not be able to specify a
  663. minimum required version with C<use $module versionnum>.
  664.  
  665. EOF
  666.     }
  667.     else {
  668.         $opt_B = $beta_version;
  669.     }
  670. }
  671.  
  672. # -A implies -c.
  673. $skip_autoloader = $opt_c = 1 if $opt_A;
  674.  
  675. # -X implies -c and -f
  676. $opt_c = $opt_f = 1 if $opt_X;
  677.  
  678. $opt_t ||= 'IV';
  679.  
  680. my %const_xsub;
  681. %const_xsub = map { $_,1 } split(/,+/, $opt_s) if $opt_s;
  682.  
  683. my $extralibs = '';
  684.  
  685. my @path_h;
  686.  
  687. while (my $arg = shift) {
  688.     if ($arg =~ /^-l/i) {
  689.         $extralibs .= "$arg ";
  690.         next;
  691.     }
  692.     last if $extralibs;
  693.     push(@path_h, $arg);
  694. }
  695.  
  696. usage "Must supply header file or module name\n"
  697.         unless (@path_h or $opt_n);
  698.  
  699. my $fmask;
  700. my $tmask;
  701.  
  702. $fmask = qr{$opt_M} if defined $opt_M;
  703. $tmask = qr{$opt_o} if defined $opt_o;
  704. my $tmask_all = $tmask && $opt_o eq '.';
  705.  
  706. if ($opt_x) {
  707.   eval {require C::Scan; 1}
  708.     or die <<EOD;
  709. C::Scan required if you use -x option.
  710. To install C::Scan, execute
  711.    perl -MCPAN -e "install C::Scan"
  712. EOD
  713.   unless ($tmask_all) {
  714.     $C::Scan::VERSION >= 0.70
  715.       or die <<EOD;
  716. C::Scan v. 0.70 or later required unless you use -o . option.
  717. You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
  718. To install C::Scan, execute
  719.    perl -MCPAN -e "install C::Scan"
  720. EOD
  721.   }
  722.   if (($opt_m || $opt_a) && $C::Scan::VERSION < 0.73) {
  723.     die <<EOD;
  724. C::Scan v. 0.73 or later required to use -m or -a options.
  725. You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
  726. To install C::Scan, execute
  727.    perl -MCPAN -e "install C::Scan"
  728. EOD
  729.   }
  730. }
  731. elsif ($opt_o or $opt_F) {
  732.   warn <<EOD if $opt_o;
  733. Option -o does not make sense without -x.
  734. EOD
  735.   warn <<EOD if $opt_F and $opt_X ;
  736. Option -F does not make sense with -X.
  737. EOD
  738. }
  739.  
  740. my @path_h_ini = @path_h;
  741. my ($name, %fullpath, %prefix, %seen_define, %prefixless, %const_names);
  742.  
  743. my $module = $opt_n;
  744.  
  745. if( @path_h ){
  746.     use File::Spec;
  747.     my @paths;
  748.     my $pre_sub_tri_graphs = 1;
  749.     if ($^O eq 'VMS') {  # Consider overrides of default location
  750.       # XXXX This is not equivalent to what the older version did:
  751.       #        it was looking at $hadsys header-file per header-file...
  752.       my($hadsys) = grep s!^sys/!!i , @path_h;
  753.       @paths = qw( Sys$Library VAXC$Include );
  754.       push @paths, ($hadsys ? 'GNU_CC_Include[vms]' : 'GNU_CC_Include[000000]');
  755.       push @paths, qw( DECC$Library_Include DECC$System_Include );
  756.     }
  757.     else {
  758.       @paths = (File::Spec->curdir(), $Config{usrinc},
  759.         (split ' ', $Config{locincpth}), '/usr/include');
  760.     }
  761.     foreach my $path_h (@path_h) {
  762.         $name ||= $path_h;
  763.     $module ||= do {
  764.       $name =~ s/\.h$//;
  765.       if ( $name !~ /::/ ) {
  766.     $name =~ s#^.*/##;
  767.     $name = "\u$name";
  768.       }
  769.       $name;
  770.     };
  771.  
  772.     if( $path_h =~ s#::#/#g && $opt_n ){
  773.     warn "Nesting of headerfile ignored with -n\n";
  774.     }
  775.     $path_h .= ".h" unless $path_h =~ /\.h$/;
  776.     my $fullpath = $path_h;
  777.     $path_h =~ s/,.*$// if $opt_x;
  778.     $fullpath{$path_h} = $fullpath;
  779.  
  780.     # Minor trickery: we can't chdir() before we processed the headers
  781.     # (so know the name of the extension), but the header may be in the
  782.     # extension directory...
  783.     my $tmp_path_h = $path_h;
  784.     my $rel_path_h = $path_h;
  785.     my @dirs = @paths;
  786.     if (not -f $path_h) {
  787.       my $found;
  788.       for my $dir (@paths) {
  789.     $found++, last
  790.       if -f ($path_h = File::Spec->catfile($dir, $tmp_path_h));
  791.       }
  792.       if ($found) {
  793.     $rel_path_h = $path_h;
  794.     $fullpath{$path_h} = $fullpath;
  795.       } else {
  796.     (my $epath = $module) =~ s,::,/,g;
  797.     $epath = File::Spec->catdir('ext', $epath) if -d 'ext';
  798.     $rel_path_h = File::Spec->catfile($epath, $tmp_path_h);
  799.     $path_h = $tmp_path_h;    # Used during -x
  800.     push @dirs, $epath;
  801.       }
  802.     }
  803.  
  804.     if (!$opt_c) {
  805.       die "Can't find $tmp_path_h in @dirs\n"
  806.     if ( ! $opt_f && ! -f "$rel_path_h" );
  807.       # Scan the header file (we should deal with nested header files)
  808.       # Record the names of simple #define constants into const_names
  809.             # Function prototypes are processed below.
  810.       open(CH, "<$rel_path_h") || die "Can't open $rel_path_h: $!\n";
  811.     defines:
  812.       while (<CH>) {
  813.     if ($pre_sub_tri_graphs) {
  814.         # Preprocess all tri-graphs
  815.         # including things stuck in quoted string constants.
  816.         s/\?\?=/#/g;                         # | ??=|  #|
  817.         s/\?\?\!/|/g;                        # | ??!|  ||
  818.         s/\?\?'/^/g;                         # | ??'|  ^|
  819.         s/\?\?\(/[/g;                        # | ??(|  [|
  820.         s/\?\?\)/]/g;                        # | ??)|  ]|
  821.         s/\?\?\-/~/g;                        # | ??-|  ~|
  822.         s/\?\?\//\\/g;                       # | ??/|  \|
  823.         s/\?\?</{/g;                         # | ??<|  {|
  824.         s/\?\?>/}/g;                         # | ??>|  }|
  825.     }
  826.     if (/^[ \t]*#[ \t]*define\s+([\$\w]+)\b(?!\()\s*(?=[^"\s])(.*)/) {
  827.         my $def = $1;
  828.         my $rest = $2;
  829.         $rest =~ s!/\*.*?(\*/|\n)|//.*!!g; # Remove comments
  830.         $rest =~ s/^\s+//;
  831.         $rest =~ s/\s+$//;
  832.         # Cannot do: (-1) and ((LHANDLE)3) are OK:
  833.         #print("Skip non-wordy $def => $rest\n"),
  834.         #  next defines if $rest =~ /[^\w\$]/;
  835.         if ($rest =~ /"/) {
  836.           print("Skip stringy $def => $rest\n") if $opt_d;
  837.           next defines;
  838.         }
  839.         print "Matched $_ ($def)\n" if $opt_d;
  840.         $seen_define{$def} = $rest;
  841.         $_ = $def;
  842.         next if /^_.*_h_*$/i; # special case, but for what?
  843.         if (defined $opt_p) {
  844.           if (!/^$opt_p(\d)/) {
  845.         ++$prefix{$_} if s/^$opt_p//;
  846.           }
  847.           else {
  848.         warn "can't remove $opt_p prefix from '$_'!\n";
  849.           }
  850.         }
  851.         $prefixless{$def} = $_;
  852.         if (!$fmask or /$fmask/) {
  853.         print "... Passes mask of -M.\n" if $opt_d and $fmask;
  854.         $const_names{$_}++;
  855.         }
  856.       }
  857.       }
  858.       if (defined $opt_e and !$opt_e) {
  859.         close(CH);
  860.       }
  861.       else {
  862.     # Work from miniperl too - on "normal" systems
  863.         my $SEEK_SET = eval 'use Fcntl qw/SEEK_SET/; SEEK_SET' or 0;
  864.         seek CH, 0, $SEEK_SET;
  865.         my $src = do { local $/; <CH> };
  866.         close CH;
  867.         no warnings 'uninitialized';
  868.  
  869.         # Remove C and C++ comments
  870.         $src =~ s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#$2#gs;
  871.  
  872.     while ($src =~ /\benum\s*([\w_]*)\s*\{\s([^}]+)\}/gsc) {
  873.         my ($enum_name, $enum_body) = ($1, $2);
  874.             # skip enums matching $opt_e
  875.             next if $opt_e && $enum_name =~ /$opt_e/;
  876.             my $val = 0;
  877.             for my $item (split /,/, $enum_body) {
  878.                 next if $item =~ /\A\s*\Z/;
  879.                 my ($key, $declared_val) = $item =~ /(\w+)\s*(?:=\s*(.*))?/;
  880.                 $val = defined($declared_val) && length($declared_val) ? $declared_val : 1 + $val;
  881.                 $seen_define{$key} = $val;
  882.                 $const_names{$key}++;
  883.             }
  884.         } # while (...)
  885.       } # if (!defined $opt_e or $opt_e)
  886.     }
  887.     }
  888. }
  889.  
  890. # Save current directory so that C::Scan can use it
  891. my $cwd = File::Spec->rel2abs( File::Spec->curdir );
  892.  
  893. # As Ilya suggested, use a name that contains - and then it can't clash with
  894. # the names of any packages. A directory 'fallback' will clash with any
  895. # new pragmata down the fallback:: tree, but that seems unlikely.
  896. my $constscfname = 'const-c.inc';
  897. my $constsxsfname = 'const-xs.inc';
  898. my $fallbackdirname = 'fallback';
  899.  
  900. my $ext = chdir 'ext' ? 'ext/' : '';
  901.  
  902. my @modparts  = split(/::/,$module);
  903. my $modpname  = join('-', @modparts);
  904. my $modfname  = pop @modparts;
  905. my $modpmdir  = join '/', 'lib', @modparts;
  906. my $modpmname = join '/', $modpmdir, $modfname.'.pm';
  907.  
  908. if ($opt_O) {
  909.     warn "Overwriting existing $ext$modpname!!!\n" if -e $modpname;
  910. }
  911. else {
  912.     die "Won't overwrite existing $ext$modpname\n" if -e $modpname;
  913. }
  914. -d "$modpname"   || mkpath([$modpname], 0, 0775);
  915. chdir($modpname) || die "Can't chdir $ext$modpname: $!\n";
  916.  
  917. my %types_seen;
  918. my %std_types;
  919. my $fdecls = [];
  920. my $fdecls_parsed = [];
  921. my $typedef_rex;
  922. my %typedefs_pre;
  923. my %known_fnames;
  924. my %structs;
  925.  
  926. my @fnames;
  927. my @fnames_no_prefix;
  928. my %vdecl_hash;
  929. my @vdecls;
  930.  
  931. if( ! $opt_X ){  # use XS, unless it was disabled
  932.   unless ($skip_ppport) {
  933.     require Devel::PPPort;
  934.     warn "Writing $ext$modpname/ppport.h\n";
  935.     Devel::PPPort::WriteFile('ppport.h')
  936.         || die "Can't create $ext$modpname/ppport.h: $!\n";
  937.   }
  938.   open(XS, ">$modfname.xs") || die "Can't create $ext$modpname/$modfname.xs: $!\n";
  939.   if ($opt_x) {
  940.     warn "Scanning typemaps...\n";
  941.     get_typemap();
  942.     my @td;
  943.     my @good_td;
  944.     my $addflags = $opt_F || '';
  945.  
  946.     foreach my $filename (@path_h) {
  947.       my $c;
  948.       my $filter;
  949.  
  950.       if ($fullpath{$filename} =~ /,/) {
  951.     $filename = $`;
  952.     $filter = $';
  953.       }
  954.       warn "Scanning $filename for functions...\n";
  955.       my @styles = $Config{gccversion} ? qw(C++ C9X GNU) : qw(C++ C9X);
  956.       $c = new C::Scan 'filename' => $filename, 'filename_filter' => $filter,
  957.     'add_cppflags' => $addflags, 'c_styles' => \@styles;
  958.       $c->set('includeDirs' => ["$Config::Config{archlib}/CORE", $cwd]);
  959.  
  960.       $c->get('keywords')->{'__restrict'} = 1;
  961.  
  962.       push @$fdecls_parsed, @{ $c->get('parsed_fdecls') };
  963.       push(@$fdecls, @{$c->get('fdecls')});
  964.  
  965.       push @td, @{$c->get('typedefs_maybe')};
  966.       if ($opt_a) {
  967.     my $structs = $c->get('typedef_structs');
  968.     @structs{keys %$structs} = values %$structs;
  969.       }
  970.  
  971.       if ($opt_m) {
  972.     %vdecl_hash = %{ $c->get('vdecl_hash') };
  973.     @vdecls = sort keys %vdecl_hash;
  974.     for (local $_ = 0; $_ < @vdecls; ++$_) {
  975.       my $var = $vdecls[$_];
  976.       my($type, $post) = @{ $vdecl_hash{$var} };
  977.       if (defined $post) {
  978.         warn "Can't handle variable '$type $var $post', skipping.\n";
  979.         splice @vdecls, $_, 1;
  980.         redo;
  981.       }
  982.       $type = normalize_type($type);
  983.       $vdecl_hash{$var} = $type;
  984.     }
  985.       }
  986.  
  987.       unless ($tmask_all) {
  988.     warn "Scanning $filename for typedefs...\n";
  989.     my $td = $c->get('typedef_hash');
  990.     # eval {require 'dumpvar.pl'; ::dumpValue($td)} or warn $@ if $opt_d;
  991.     my @f_good_td = grep $td->{$_}[1] eq '', keys %$td;
  992.     push @good_td, @f_good_td;
  993.     @typedefs_pre{@f_good_td}  = map $_->[0], @$td{@f_good_td};
  994.       }
  995.     }
  996.     { local $" = '|';
  997.       $typedef_rex = qr(\b(?<!struct )(?:@good_td)\b) if @good_td;
  998.     }
  999.     %known_fnames = map @$_[1,3], @$fdecls_parsed; # [1,3] is NAME, FULLTEXT
  1000.     if ($fmask) {
  1001.       my @good;
  1002.       for my $i (0..$#$fdecls_parsed) {
  1003.     next unless $fdecls_parsed->[$i][1] =~ /$fmask/; # [1] is NAME
  1004.     push @good, $i;
  1005.     print "... Function $fdecls_parsed->[$i][1] passes -M mask.\n"
  1006.       if $opt_d;
  1007.       }
  1008.       $fdecls = [@$fdecls[@good]];
  1009.       $fdecls_parsed = [@$fdecls_parsed[@good]];
  1010.     }
  1011.     @fnames = sort map $_->[1], @$fdecls_parsed; # 1 is NAME
  1012.     # Sort declarations:
  1013.     {
  1014.       my %h = map( ($_->[1], $_), @$fdecls_parsed);
  1015.       $fdecls_parsed = [ @h{@fnames} ];
  1016.     }
  1017.     @fnames_no_prefix = @fnames;
  1018.     @fnames_no_prefix
  1019.       = sort map { ++$prefix{$_} if s/^$opt_p(?!\d)//; $_ } @fnames_no_prefix
  1020.          if defined $opt_p;
  1021.     # Remove macros which expand to typedefs
  1022.     print "Typedefs are @td.\n" if $opt_d;
  1023.     my %td = map {($_, $_)} @td;
  1024.     # Add some other possible but meaningless values for macros
  1025.     for my $k (qw(char double float int long short unsigned signed void)) {
  1026.       $td{"$_$k"} = "$_$k" for ('', 'signed ', 'unsigned ');
  1027.     }
  1028.     # eval {require 'dumpvar.pl'; ::dumpValue( [\@td, \%td] ); 1} or warn $@;
  1029.     my $n = 0;
  1030.     my %bad_macs;
  1031.     while (keys %td > $n) {
  1032.       $n = keys %td;
  1033.       my ($k, $v);
  1034.       while (($k, $v) = each %seen_define) {
  1035.     # print("found '$k'=>'$v'\n"),
  1036.     $bad_macs{$k} = $td{$k} = $td{$v} if exists $td{$v};
  1037.       }
  1038.     }
  1039.     # Now %bad_macs contains names of bad macros
  1040.     for my $k (keys %bad_macs) {
  1041.       delete $const_names{$prefixless{$k}};
  1042.       print "Ignoring macro $k which expands to a typedef name '$bad_macs{$k}'\n" if $opt_d;
  1043.     }
  1044.   }
  1045. }
  1046. my @const_names = sort keys %const_names;
  1047.  
  1048. -d $modpmdir || mkpath([$modpmdir], 0, 0775);
  1049. open(PM, ">$modpmname") || die "Can't create $ext$modpname/$modpmname: $!\n";
  1050.  
  1051. $" = "\n\t";
  1052. warn "Writing $ext$modpname/$modpmname\n";
  1053.  
  1054. print PM <<"END";
  1055. package $module;
  1056.  
  1057. use $compat_version;
  1058. END
  1059.  
  1060. print PM <<"END" unless $skip_strict;
  1061. use strict;
  1062. END
  1063.  
  1064. print PM "use warnings;\n" unless $skip_warnings or $compat_version < 5.006;
  1065.  
  1066. unless( $opt_X || $opt_c || $opt_A ){
  1067.     # we'll have an AUTOLOAD(), and it will have $AUTOLOAD and
  1068.     # will want Carp.
  1069.     print PM <<'END';
  1070. use Carp;
  1071. END
  1072. }
  1073.  
  1074. print PM <<'END' unless $skip_exporter;
  1075.  
  1076. require Exporter;
  1077. END
  1078.  
  1079. my $use_Dyna = (not $opt_X and $compat_version < 5.006 and not $use_xsloader);
  1080. print PM <<"END" if $use_Dyna;  # use DynaLoader, unless XS was disabled
  1081. require DynaLoader;
  1082. END
  1083.  
  1084.  
  1085. # Are we using AutoLoader or not?
  1086. unless ($skip_autoloader) { # no autoloader whatsoever.
  1087.     unless ($opt_c) { # we're doing the AUTOLOAD
  1088.         print PM "use AutoLoader;\n";
  1089.     }
  1090.     else {
  1091.         print PM "use AutoLoader qw(AUTOLOAD);\n"
  1092.     }
  1093. }
  1094.  
  1095. if ( $compat_version < 5.006 ) {
  1096.     my $vars = '$VERSION @ISA';
  1097.     $vars .= ' @EXPORT @EXPORT_OK %EXPORT_TAGS' unless $skip_exporter;
  1098.     $vars .= ' $AUTOLOAD' unless $opt_X || $opt_c || $opt_A;
  1099.     $vars .= ' $XS_VERSION' if $opt_B && !$opt_X;
  1100.     print PM "use vars qw($vars);";
  1101. }
  1102.  
  1103. # Determine @ISA.
  1104. my @modISA;
  1105. push @modISA, 'Exporter'    unless $skip_exporter;
  1106. push @modISA, 'DynaLoader'     if $use_Dyna;  # no XS
  1107. my $myISA = "our \@ISA = qw(@modISA);";
  1108. $myISA =~ s/^our // if $compat_version < 5.006;
  1109.  
  1110. print PM "\n$myISA\n\n";
  1111.  
  1112. my @exported_names = (@const_names, @fnames_no_prefix, map '$'.$_, @vdecls);
  1113.  
  1114. my $tmp='';
  1115. $tmp .= <<"END" unless $skip_exporter;
  1116. # Items to export into callers namespace by default. Note: do not export
  1117. # names by default without a very good reason. Use EXPORT_OK instead.
  1118. # Do not simply export all your public functions/methods/constants.
  1119.  
  1120. # This allows declaration    use $module ':all';
  1121. # If you do not need this, moving things directly into \@EXPORT or \@EXPORT_OK
  1122. # will save memory.
  1123. our %EXPORT_TAGS = ( 'all' => [ qw(
  1124.     @exported_names
  1125. ) ] );
  1126.  
  1127. our \@EXPORT_OK = ( \@{ \$EXPORT_TAGS{'all'} } );
  1128.  
  1129. our \@EXPORT = qw(
  1130.     @const_names
  1131. );
  1132.  
  1133. END
  1134.  
  1135. $tmp .= "our \$VERSION = '$TEMPLATE_VERSION';\n";
  1136. if ($opt_B) {
  1137.     $tmp .= "our \$XS_VERSION = \$VERSION;\n" unless $opt_X;
  1138.     $tmp .= "\$VERSION = eval \$VERSION;  # see L<perlmodstyle>\n";
  1139. }
  1140. $tmp .= "\n";
  1141.  
  1142. $tmp =~ s/^our //mg if $compat_version < 5.006;
  1143. print PM $tmp;
  1144.  
  1145. if (@vdecls) {
  1146.     printf PM "our(@{[ join ', ', map '$'.$_, @vdecls ]});\n\n";
  1147. }
  1148.  
  1149.  
  1150. print PM autoload ($module, $compat_version) unless $opt_c or $opt_X;
  1151.  
  1152. if( ! $opt_X ){ # print bootstrap, unless XS is disabled
  1153.   if ($use_Dyna) {
  1154.     $tmp = <<"END";
  1155. bootstrap $module \$VERSION;
  1156. END
  1157.   } else {
  1158.     $tmp = <<"END";
  1159. require XSLoader;
  1160. XSLoader::load('$module', \$VERSION);
  1161. END
  1162.   }
  1163.   $tmp =~ s:\$VERSION:\$XS_VERSION:g if $opt_B;
  1164.   print PM $tmp;
  1165. }
  1166.  
  1167. # tying the variables can happen only after bootstrap
  1168. if (@vdecls) {
  1169.     printf PM <<END;
  1170. {
  1171. @{[ join "\n", map "    _tievar_$_(\$$_);", @vdecls ]}
  1172. }
  1173.  
  1174. END
  1175. }
  1176.  
  1177. my $after;
  1178. if( $opt_P ){ # if POD is disabled
  1179.     $after = '__END__';
  1180. }
  1181. else {
  1182.     $after = '=cut';
  1183. }
  1184.  
  1185. print PM <<"END";
  1186.  
  1187. # Preloaded methods go here.
  1188. END
  1189.  
  1190. print PM <<"END" unless $opt_A;
  1191.  
  1192. # Autoload methods go after $after, and are processed by the autosplit program.
  1193. END
  1194.  
  1195. print PM <<"END";
  1196.  
  1197. 1;
  1198. __END__
  1199. END
  1200.  
  1201. my ($email,$author,$licence);
  1202.  
  1203. eval {
  1204.        my $username;
  1205.        ($username,$author) = (getpwuid($>))[0,6];
  1206.        if (defined $username && defined $author) {
  1207.        $author =~ s/,.*$//; # in case of sub fields
  1208.        my $domain = $Config{'mydomain'};
  1209.        $domain =~ s/^\.//;
  1210.        $email = "$username\@$domain";
  1211.        }
  1212.      };
  1213.  
  1214. $author =~ s/'/\\'/g if defined $author;
  1215. $author ||= "A. U. Thor";
  1216. $email  ||= 'a.u.thor@a.galaxy.far.far.away';
  1217.  
  1218. $licence = sprintf << "DEFAULT", $^V;
  1219. Copyright (C) ${\(1900 + (localtime) [5])} by $author
  1220.  
  1221. This library is free software; you can redistribute it and/or modify
  1222. it under the same terms as Perl itself, either Perl version %vd or,
  1223. at your option, any later version of Perl 5 you may have available.
  1224. DEFAULT
  1225.  
  1226. my $revhist = '';
  1227. $revhist = <<EOT if $opt_C;
  1228. #
  1229. #=head1 HISTORY
  1230. #
  1231. #=over 8
  1232. #
  1233. #=item $TEMPLATE_VERSION
  1234. #
  1235. #Original version; created by h2xs $H2XS_VERSION with options
  1236. #
  1237. #  @ARGS
  1238. #
  1239. #=back
  1240. #
  1241. EOT
  1242.  
  1243. my $exp_doc = $skip_exporter ? '' : <<EOD;
  1244. #
  1245. #=head2 EXPORT
  1246. #
  1247. #None by default.
  1248. #
  1249. EOD
  1250.  
  1251. if (@const_names and not $opt_P) {
  1252.   $exp_doc .= <<EOD unless $skip_exporter;
  1253. #=head2 Exportable constants
  1254. #
  1255. #  @{[join "\n  ", @const_names]}
  1256. #
  1257. EOD
  1258. }
  1259.  
  1260. if (defined $fdecls and @$fdecls and not $opt_P) {
  1261.   $exp_doc .= <<EOD unless $skip_exporter;
  1262. #=head2 Exportable functions
  1263. #
  1264. EOD
  1265.  
  1266. #  $exp_doc .= <<EOD if $opt_p;
  1267. #When accessing these functions from Perl, prefix C<$opt_p> should be removed.
  1268. #
  1269. #EOD
  1270.   $exp_doc .= <<EOD unless $skip_exporter;
  1271. #  @{[join "\n  ", @known_fnames{@fnames}]}
  1272. #
  1273. EOD
  1274. }
  1275.  
  1276. my $meth_doc = '';
  1277.  
  1278. if ($opt_x && $opt_a) {
  1279.   my($name, $struct);
  1280.   $meth_doc .= accessor_docs($name, $struct)
  1281.     while ($name, $struct) = each %structs;
  1282. }
  1283.  
  1284. # Prefix the default licence with hash symbols.
  1285. # Is this just cargo cult - it seems that the first thing that happens to this
  1286. # block is that all the hashes are then s///g out.
  1287. my $licence_hash = $licence;
  1288. $licence_hash =~ s/^/#/gm;
  1289.  
  1290. my $pod;
  1291. $pod = <<"END" unless $opt_P;
  1292. ## Below is stub documentation for your module. You'd better edit it!
  1293. #
  1294. #=head1 NAME
  1295. #
  1296. #$module - Perl extension for blah blah blah
  1297. #
  1298. #=head1 SYNOPSIS
  1299. #
  1300. #  use $module;
  1301. #  blah blah blah
  1302. #
  1303. #=head1 DESCRIPTION
  1304. #
  1305. #Stub documentation for $module, created by h2xs. It looks like the
  1306. #author of the extension was negligent enough to leave the stub
  1307. #unedited.
  1308. #
  1309. #Blah blah blah.
  1310. $exp_doc$meth_doc$revhist
  1311. #
  1312. #=head1 SEE ALSO
  1313. #
  1314. #Mention other useful documentation such as the documentation of
  1315. #related modules or operating system documentation (such as man pages
  1316. #in UNIX), or any relevant external documentation such as RFCs or
  1317. #standards.
  1318. #
  1319. #If you have a mailing list set up for your module, mention it here.
  1320. #
  1321. #If you have a web site set up for your module, mention it here.
  1322. #
  1323. #=head1 AUTHOR
  1324. #
  1325. #$author, E<lt>${email}E<gt>
  1326. #
  1327. #=head1 COPYRIGHT AND LICENSE
  1328. #
  1329. $licence_hash
  1330. #
  1331. #=cut
  1332. END
  1333.  
  1334. $pod =~ s/^\#//gm unless $opt_P;
  1335. print PM $pod unless $opt_P;
  1336.  
  1337. close PM;
  1338.  
  1339.  
  1340. if( ! $opt_X ){ # print XS, unless it is disabled
  1341. warn "Writing $ext$modpname/$modfname.xs\n";
  1342.  
  1343. print XS <<"END";
  1344. #include "EXTERN.h"
  1345. #include "perl.h"
  1346. #include "XSUB.h"
  1347.  
  1348. END
  1349.  
  1350. print XS <<"END" unless $skip_ppport;
  1351. #include "ppport.h"
  1352.  
  1353. END
  1354.  
  1355. if( @path_h ){
  1356.     foreach my $path_h (@path_h_ini) {
  1357.     my($h) = $path_h;
  1358.     $h =~ s#^/usr/include/##;
  1359.     if ($^O eq 'VMS') { $h =~ s#.*vms\]#sys/# or $h =~ s#.*[:>\]]##; }
  1360.         print XS qq{#include <$h>\n};
  1361.     }
  1362.     print XS "\n";
  1363. }
  1364.  
  1365. print XS <<"END" if $opt_g;
  1366.  
  1367. /* Global Data */
  1368.  
  1369. #define MY_CXT_KEY "${module}::_guts" XS_VERSION
  1370.  
  1371. typedef struct {
  1372.     /* Put Global Data in here */
  1373.     int dummy;        /* you can access this elsewhere as MY_CXT.dummy */
  1374. } my_cxt_t;
  1375.  
  1376. START_MY_CXT
  1377.  
  1378. END
  1379.  
  1380. my %pointer_typedefs;
  1381. my %struct_typedefs;
  1382.  
  1383. sub td_is_pointer {
  1384.   my $type = shift;
  1385.   my $out = $pointer_typedefs{$type};
  1386.   return $out if defined $out;
  1387.   my $otype = $type;
  1388.   $out = ($type =~ /\*$/);
  1389.   # This converts only the guys which do not have trailing part in the typedef
  1390.   if (not $out
  1391.       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
  1392.     $type = normalize_type($type);
  1393.     print "Is-Pointer: Type mutation via typedefs: $otype ==> $type\n"
  1394.       if $opt_d;
  1395.     $out = td_is_pointer($type);
  1396.   }
  1397.   return ($pointer_typedefs{$otype} = $out);
  1398. }
  1399.  
  1400. sub td_is_struct {
  1401.   my $type = shift;
  1402.   my $out = $struct_typedefs{$type};
  1403.   return $out if defined $out;
  1404.   my $otype = $type;
  1405.   $out = ($type =~ /^(struct|union)\b/) && !td_is_pointer($type);
  1406.   # This converts only the guys which do not have trailing part in the typedef
  1407.   if (not $out
  1408.       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
  1409.     $type = normalize_type($type);
  1410.     print "Is-Struct: Type mutation via typedefs: $otype ==> $type\n"
  1411.       if $opt_d;
  1412.     $out = td_is_struct($type);
  1413.   }
  1414.   return ($struct_typedefs{$otype} = $out);
  1415. }
  1416.  
  1417. print_tievar_subs(\*XS, $_, $vdecl_hash{$_}) for @vdecls;
  1418.  
  1419. if( ! $opt_c ) {
  1420.   # We write the "sample" files used when this module is built by perl without
  1421.   # ExtUtils::Constant.
  1422.   # h2xs will later check that these are the same as those generated by the
  1423.   # code embedded into Makefile.PL
  1424.   unless (-d $fallbackdirname) {
  1425.     mkdir "$fallbackdirname" or die "Cannot mkdir $fallbackdirname: $!\n";
  1426.   }
  1427.   warn "Writing $ext$modpname/$fallbackdirname/$constscfname\n";
  1428.   warn "Writing $ext$modpname/$fallbackdirname/$constsxsfname\n";
  1429.   my $cfallback = File::Spec->catfile($fallbackdirname, $constscfname);
  1430.   my $xsfallback = File::Spec->catfile($fallbackdirname, $constsxsfname);
  1431.   WriteConstants ( C_FILE =>       $cfallback,
  1432.                    XS_FILE =>      $xsfallback,
  1433.                    DEFAULT_TYPE => $opt_t,
  1434.                    NAME =>         $module,
  1435.                    NAMES =>        \@const_names,
  1436.                  );
  1437.   print XS "#include \"$constscfname\"\n";
  1438. }
  1439.  
  1440.  
  1441. my $prefix = defined $opt_p ? "PREFIX = $opt_p" : '';
  1442.  
  1443. # Now switch from C to XS by issuing the first MODULE declaration:
  1444. print XS <<"END";
  1445.  
  1446. MODULE = $module        PACKAGE = $module        $prefix
  1447.  
  1448. END
  1449.  
  1450. # If a constant() function was #included then output a corresponding
  1451. # XS declaration:
  1452. print XS "INCLUDE: $constsxsfname\n" unless $opt_c;
  1453.  
  1454. print XS <<"END" if $opt_g;
  1455.  
  1456. BOOT:
  1457. {
  1458.     MY_CXT_INIT;
  1459.     /* If any of the fields in the my_cxt_t struct need
  1460.        to be initialised, do it here.
  1461.      */
  1462. }
  1463.  
  1464. END
  1465.  
  1466. foreach (sort keys %const_xsub) {
  1467.     print XS <<"END";
  1468. char *
  1469. $_()
  1470.  
  1471.     CODE:
  1472. #ifdef $_
  1473.     RETVAL = $_;
  1474. #else
  1475.     croak("Your vendor has not defined the $module macro $_");
  1476. #endif
  1477.  
  1478.     OUTPUT:
  1479.     RETVAL
  1480.  
  1481. END
  1482. }
  1483.  
  1484. my %seen_decl;
  1485. my %typemap;
  1486.  
  1487. sub print_decl {
  1488.   my $fh = shift;
  1489.   my $decl = shift;
  1490.   my ($type, $name, $args) = @$decl;
  1491.   return if $seen_decl{$name}++; # Need to do the same for docs as well?
  1492.  
  1493.   my @argnames = map {$_->[1]} @$args;
  1494.   my @argtypes = map { normalize_type( $_->[0], 1 ) } @$args;
  1495.   if ($opt_k) {
  1496.     s/^\s*const\b\s*// for @argtypes;
  1497.   }
  1498.   my @argarrays = map { $_->[4] || '' } @$args;
  1499.   my $numargs = @$args;
  1500.   if ($numargs and $argtypes[-1] eq '...') {
  1501.     $numargs--;
  1502.     $argnames[-1] = '...';
  1503.   }
  1504.   local $" = ', ';
  1505.   $type = normalize_type($type, 1);
  1506.  
  1507.   print $fh <<"EOP";
  1508.  
  1509. $type
  1510. $name(@argnames)
  1511. EOP
  1512.  
  1513.   for my $arg (0 .. $numargs - 1) {
  1514.     print $fh <<"EOP";
  1515.     $argtypes[$arg]    $argnames[$arg]$argarrays[$arg]
  1516. EOP
  1517.   }
  1518. }
  1519.  
  1520. sub print_tievar_subs {
  1521.   my($fh, $name, $type) = @_;
  1522.   print $fh <<END;
  1523. I32
  1524. _get_$name(IV index, SV *sv) {
  1525.     dSP;
  1526.     PUSHMARK(SP);
  1527.     XPUSHs(sv);
  1528.     PUTBACK;
  1529.     (void)call_pv("$module\::_get_$name", G_DISCARD);
  1530.     return (I32)0;
  1531. }
  1532.  
  1533. I32
  1534. _set_$name(IV index, SV *sv) {
  1535.     dSP;
  1536.     PUSHMARK(SP);
  1537.     XPUSHs(sv);
  1538.     PUTBACK;
  1539.     (void)call_pv("$module\::_set_$name", G_DISCARD);
  1540.     return (I32)0;
  1541. }
  1542.  
  1543. END
  1544. }
  1545.  
  1546. sub print_tievar_xsubs {
  1547.   my($fh, $name, $type) = @_;
  1548.   print $fh <<END;
  1549. void
  1550. _tievar_$name(sv)
  1551.     SV* sv
  1552.     PREINIT:
  1553.     struct ufuncs uf;
  1554.     CODE:
  1555.     uf.uf_val = &_get_$name;
  1556.     uf.uf_set = &_set_$name;
  1557.     uf.uf_index = (IV)&_get_$name;
  1558.     sv_magic(sv, 0, 'U', (char*)&uf, sizeof(uf));
  1559.  
  1560. void
  1561. _get_$name(THIS)
  1562.     $type THIS = NO_INIT
  1563.     CODE:
  1564.     THIS = $name;
  1565.     OUTPUT:
  1566.     SETMAGIC: DISABLE
  1567.     THIS
  1568.  
  1569. void
  1570. _set_$name(THIS)
  1571.     $type THIS
  1572.     CODE:
  1573.     $name = THIS;
  1574.  
  1575. END
  1576. }
  1577.  
  1578. sub print_accessors {
  1579.   my($fh, $name, $struct) = @_;
  1580.   return unless defined $struct && $name !~ /\s|_ANON/;
  1581.   $name = normalize_type($name);
  1582.   my $ptrname = normalize_type("$name *");
  1583.   print $fh <<"EOF";
  1584.  
  1585. MODULE = $module        PACKAGE = ${name}        $prefix
  1586.  
  1587. $name *
  1588. _to_ptr(THIS)
  1589.     $name THIS = NO_INIT
  1590.     PROTOTYPE: \$
  1591.     CODE:
  1592.     if (sv_derived_from(ST(0), "$name")) {
  1593.         STRLEN len;
  1594.         char *s = SvPV((SV*)SvRV(ST(0)), len);
  1595.         if (len != sizeof(THIS))
  1596.         croak("Size \%d of packed data != expected \%d",
  1597.             len, sizeof(THIS));
  1598.         RETVAL = ($name *)s;
  1599.     }
  1600.     else
  1601.         croak("THIS is not of type $name");
  1602.     OUTPUT:
  1603.     RETVAL
  1604.  
  1605. $name
  1606. new(CLASS)
  1607.     char *CLASS = NO_INIT
  1608.     PROTOTYPE: \$
  1609.     CODE:
  1610.     Zero((void*)&RETVAL, sizeof(RETVAL), char);
  1611.     OUTPUT:
  1612.     RETVAL
  1613.  
  1614. MODULE = $module        PACKAGE = ${name}Ptr        $prefix
  1615.  
  1616. EOF
  1617.   my @items = @$struct;
  1618.   while (@items) {
  1619.     my $item = shift @items;
  1620.     if ($item->[0] =~ /_ANON/) {
  1621.       if (defined $item->[2]) {
  1622.     push @items, map [
  1623.       @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
  1624.     ], @{ $structs{$item->[0]} };
  1625.       } else {
  1626.     push @items, @{ $structs{$item->[0]} };
  1627.       }
  1628.     } else {
  1629.       my $type = normalize_type($item->[0]);
  1630.       my $ttype = $structs{$type} ? normalize_type("$type *") : $type;
  1631.       print $fh <<"EOF";
  1632. $ttype
  1633. $item->[2](THIS, __value = NO_INIT)
  1634.     $ptrname THIS
  1635.     $type __value
  1636.     PROTOTYPE: \$;\$
  1637.     CODE:
  1638.     if (items > 1)
  1639.         THIS->$item->[-1] = __value;
  1640.     RETVAL = @{[
  1641.         $type eq $ttype ? "THIS->$item->[-1]" : "&(THIS->$item->[-1])"
  1642.     ]};
  1643.     OUTPUT:
  1644.     RETVAL
  1645.  
  1646. EOF
  1647.     }
  1648.   }
  1649. }
  1650.  
  1651. sub accessor_docs {
  1652.   my($name, $struct) = @_;
  1653.   return unless defined $struct && $name !~ /\s|_ANON/;
  1654.   $name = normalize_type($name);
  1655.   my $ptrname = $name . 'Ptr';
  1656.   my @items = @$struct;
  1657.   my @list;
  1658.   while (@items) {
  1659.     my $item = shift @items;
  1660.     if ($item->[0] =~ /_ANON/) {
  1661.       if (defined $item->[2]) {
  1662.     push @items, map [
  1663.       @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
  1664.     ], @{ $structs{$item->[0]} };
  1665.       } else {
  1666.     push @items, @{ $structs{$item->[0]} };
  1667.       }
  1668.     } else {
  1669.       push @list, $item->[2];
  1670.     }
  1671.   }
  1672.   my $methods = (join '(...)>, C<', @list) . '(...)';
  1673.  
  1674.   my $pod = <<"EOF";
  1675. #
  1676. #=head2 Object and class methods for C<$name>/C<$ptrname>
  1677. #
  1678. #The principal Perl representation of a C object of type C<$name> is an
  1679. #object of class C<$ptrname> which is a reference to an integer
  1680. #representation of a C pointer.  To create such an object, one may use
  1681. #a combination
  1682. #
  1683. #  my \$buffer = $name->new();
  1684. #  my \$obj = \$buffer->_to_ptr();
  1685. #
  1686. #This exersizes the following two methods, and an additional class
  1687. #C<$name>, the internal representation of which is a reference to a
  1688. #packed string with the C structure.  Keep in mind that \$buffer should
  1689. #better survive longer than \$obj.
  1690. #
  1691. #=over
  1692. #
  1693. #=item C<\$object_of_type_$name-E<gt>_to_ptr()>
  1694. #
  1695. #Converts an object of type C<$name> to an object of type C<$ptrname>.
  1696. #
  1697. #=item C<$name-E<gt>new()>
  1698. #
  1699. #Creates an empty object of type C<$name>.  The corresponding packed
  1700. #string is zeroed out.
  1701. #
  1702. #=item C<$methods>
  1703. #
  1704. #return the current value of the corresponding element if called
  1705. #without additional arguments.  Set the element to the supplied value
  1706. #(and return the new value) if called with an additional argument.
  1707. #
  1708. #Applicable to objects of type C<$ptrname>.
  1709. #
  1710. #=back
  1711. #
  1712. EOF
  1713.   $pod =~ s/^\#//gm;
  1714.   return $pod;
  1715. }
  1716.  
  1717. # Should be called before any actual call to normalize_type().
  1718. sub get_typemap {
  1719.   # We do not want to read ./typemap by obvios reasons.
  1720.   my @tm =  qw(../../../typemap ../../typemap ../typemap);
  1721.   my $stdtypemap =  "$Config::Config{privlib}/ExtUtils/typemap";
  1722.   unshift @tm, $stdtypemap;
  1723.   my $proto_re = "[" . quotemeta('\$%&*@;') . "]" ;
  1724.  
  1725.   # Start with useful default values
  1726.   $typemap{float} = 'T_NV';
  1727.  
  1728.   foreach my $typemap (@tm) {
  1729.     next unless -e $typemap ;
  1730.     # skip directories, binary files etc.
  1731.     warn " Scanning $typemap\n";
  1732.     warn("Warning: ignoring non-text typemap file '$typemap'\n"), next
  1733.       unless -T $typemap ;
  1734.     open(TYPEMAP, $typemap)
  1735.       or warn ("Warning: could not open typemap file '$typemap': $!\n"), next;
  1736.     my $mode = 'Typemap';
  1737.     while (<TYPEMAP>) {
  1738.       next if /^\s*\#/;
  1739.       if (/^INPUT\s*$/)   { $mode = 'Input'; next; }
  1740.       elsif (/^OUTPUT\s*$/)  { $mode = 'Output'; next; }
  1741.       elsif (/^TYPEMAP\s*$/) { $mode = 'Typemap'; next; }
  1742.       elsif ($mode eq 'Typemap') {
  1743.     next if /^\s*($|\#)/ ;
  1744.     my ($type, $image);
  1745.     if ( ($type, $image) =
  1746.          /^\s*(.*?\S)\s+(\S+)\s*($proto_re*)\s*$/o
  1747.          # This may reference undefined functions:
  1748.          and not ($image eq 'T_PACKED' and $typemap eq $stdtypemap)) {
  1749.       $typemap{normalize_type($type)} = $image;
  1750.     }
  1751.       }
  1752.     }
  1753.     close(TYPEMAP) or die "Cannot close $typemap: $!";
  1754.   }
  1755.   %std_types = %types_seen;
  1756.   %types_seen = ();
  1757. }
  1758.  
  1759.  
  1760. sub normalize_type {        # Second arg: do not strip const's before \*
  1761.   my $type = shift;
  1762.   my $do_keep_deep_const = shift;
  1763.   # If $do_keep_deep_const this is heuristical only
  1764.   my $keep_deep_const = ($do_keep_deep_const ? '\b(?![^(,)]*\*)' : '');
  1765.   my $ignore_mods
  1766.     = "(?:\\b(?:(?:__const__|const)$keep_deep_const|static|inline|__inline__)\\b\\s*)*";
  1767.   if ($do_keep_deep_const) {    # Keep different compiled /RExen/o separately!
  1768.     $type =~ s/$ignore_mods//go;
  1769.   }
  1770.   else {
  1771.     $type =~ s/$ignore_mods//go;
  1772.   }
  1773.   $type =~ s/([^\s\w])/ $1 /g;
  1774.   $type =~ s/\s+$//;
  1775.   $type =~ s/^\s+//;
  1776.   $type =~ s/\s+/ /g;
  1777.   $type =~ s/\* (?=\*)/*/g;
  1778.   $type =~ s/\. \. \./.../g;
  1779.   $type =~ s/ ,/,/g;
  1780.   $types_seen{$type}++
  1781.     unless $type eq '...' or $type eq 'void' or $std_types{$type};
  1782.   $type;
  1783. }
  1784.  
  1785. my $need_opaque;
  1786.  
  1787. sub assign_typemap_entry {
  1788.   my $type = shift;
  1789.   my $otype = $type;
  1790.   my $entry;
  1791.   if ($tmask and $type =~ /$tmask/) {
  1792.     print "Type $type matches -o mask\n" if $opt_d;
  1793.     $entry = (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
  1794.   }
  1795.   elsif ($typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
  1796.     $type = normalize_type $type;
  1797.     print "Type mutation via typedefs: $otype ==> $type\n" if $opt_d;
  1798.     $entry = assign_typemap_entry($type);
  1799.   }
  1800.   # XXX good do better if our UV happens to be long long
  1801.   return "T_NV" if $type =~ /^(unsigned\s+)?long\s+(long|double)\z/;
  1802.   $entry ||= $typemap{$otype}
  1803.     || (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
  1804.   $typemap{$otype} = $entry;
  1805.   $need_opaque = 1 if $entry eq "T_OPAQUE_STRUCT";
  1806.   return $entry;
  1807. }
  1808.  
  1809. for (@vdecls) {
  1810.   print_tievar_xsubs(\*XS, $_, $vdecl_hash{$_});
  1811. }
  1812.  
  1813. if ($opt_x) {
  1814.   for my $decl (@$fdecls_parsed) { print_decl(\*XS, $decl) }
  1815.   if ($opt_a) {
  1816.     while (my($name, $struct) = each %structs) {
  1817.       print_accessors(\*XS, $name, $struct);
  1818.     }
  1819.   }
  1820. }
  1821.  
  1822. close XS;
  1823.  
  1824. if (%types_seen) {
  1825.   my $type;
  1826.   warn "Writing $ext$modpname/typemap\n";
  1827.   open TM, ">typemap" or die "Cannot open typemap file for write: $!";
  1828.  
  1829.   for $type (sort keys %types_seen) {
  1830.     my $entry = assign_typemap_entry $type;
  1831.     print TM $type, "\t" x (5 - int((length $type)/8)), "\t$entry\n"
  1832.   }
  1833.  
  1834.   print TM <<'EOP' if $need_opaque; # Older Perls do not have correct entry
  1835. #############################################################################
  1836. INPUT
  1837. T_OPAQUE_STRUCT
  1838.     if (sv_derived_from($arg, \"${ntype}\")) {
  1839.         STRLEN len;
  1840.         char  *s = SvPV((SV*)SvRV($arg), len);
  1841.  
  1842.         if (len != sizeof($var))
  1843.         croak(\"Size %d of packed data != expected %d\",
  1844.             len, sizeof($var));
  1845.         $var = *($type *)s;
  1846.     }
  1847.     else
  1848.         croak(\"$var is not of type ${ntype}\")
  1849. #############################################################################
  1850. OUTPUT
  1851. T_OPAQUE_STRUCT
  1852.     sv_setref_pvn($arg, \"${ntype}\", (char *)&$var, sizeof($var));
  1853. EOP
  1854.  
  1855.   close TM or die "Cannot close typemap file for write: $!";
  1856. }
  1857.  
  1858. } # if( ! $opt_X )
  1859.  
  1860. warn "Writing $ext$modpname/Makefile.PL\n";
  1861. open(PL, ">Makefile.PL") || die "Can't create $ext$modpname/Makefile.PL: $!\n";
  1862.  
  1863. my $prereq_pm = '';
  1864.  
  1865. if ( $compat_version < 5.00702 and $new_test )
  1866. {
  1867.   $prereq_pm .= q%'Test::More'  =>  0, %;
  1868. }
  1869.  
  1870. if ( $compat_version < 5.00600 and !$opt_X and $use_xsloader)
  1871. {
  1872.   $prereq_pm .= q%'XSLoader'  =>  0, %;
  1873. }
  1874.  
  1875. print PL <<"END";
  1876. use $compat_version;
  1877. use ExtUtils::MakeMaker;
  1878. # See lib/ExtUtils/MakeMaker.pm for details of how to influence
  1879. # the contents of the Makefile that is written.
  1880. WriteMakefile(
  1881.     NAME              => '$module',
  1882.     VERSION_FROM      => '$modpmname', # finds \$VERSION
  1883.     PREREQ_PM         => {$prereq_pm}, # e.g., Module::Name => 1.1
  1884.     (\$] >= 5.005 ?     ## Add these new keywords supported since 5.005
  1885.       (ABSTRACT_FROM  => '$modpmname', # retrieve abstract from module
  1886.        AUTHOR         => '$author <$email>') : ()),
  1887. END
  1888. if (!$opt_X) { # print C stuff, unless XS is disabled
  1889.   $opt_F = '' unless defined $opt_F;
  1890.   my $I = (((glob '*.h') || (glob '*.hh')) ? '-I.' : '');
  1891.   my $Ihelp = ($I ? '-I. ' : '');
  1892.   my $Icomment = ($I ? '' : <<EOC);
  1893.     # Insert -I. if you add *.h files later:
  1894. EOC
  1895.  
  1896.   print PL <<END;
  1897.     LIBS              => ['$extralibs'], # e.g., '-lm'
  1898.     DEFINE            => '$opt_F', # e.g., '-DHAVE_SOMETHING'
  1899. $Icomment    INC               => '$I', # e.g., '${Ihelp}-I/usr/include/other'
  1900. END
  1901.  
  1902.   my $C = grep {$_ ne "$modfname.c"}
  1903.     (glob '*.c'), (glob '*.cc'), (glob '*.C');
  1904.   my $Cpre = ($C ? '' : '# ');
  1905.   my $Ccomment = ($C ? '' : <<EOC);
  1906.     # Un-comment this if you add C files to link with later:
  1907. EOC
  1908.  
  1909.   print PL <<END;
  1910. $Ccomment    ${Cpre}OBJECT            => '\$(O_FILES)', # link all the C files too
  1911. END
  1912. } # ' # Grr
  1913. print PL ");\n";
  1914. if (!$opt_c) {
  1915.   my $generate_code =
  1916.     WriteMakefileSnippet ( C_FILE =>       $constscfname,
  1917.                            XS_FILE =>      $constsxsfname,
  1918.                            DEFAULT_TYPE => $opt_t,
  1919.                            NAME =>         $module,
  1920.                            NAMES =>        \@const_names,
  1921.                  );
  1922.   print PL <<"END";
  1923. if  (eval {require ExtUtils::Constant; 1}) {
  1924.   # If you edit these definitions to change the constants used by this module,
  1925.   # you will need to use the generated $constscfname and $constsxsfname
  1926.   # files to replace their "fallback" counterparts before distributing your
  1927.   # changes.
  1928. $generate_code
  1929. }
  1930. else {
  1931.   use File::Copy;
  1932.   use File::Spec;
  1933.   foreach my \$file ('$constscfname', '$constsxsfname') {
  1934.     my \$fallback = File::Spec->catfile('$fallbackdirname', \$file);
  1935.     copy (\$fallback, \$file) or die "Can't copy \$fallback to \$file: \$!";
  1936.   }
  1937. }
  1938. END
  1939.  
  1940.   eval $generate_code;
  1941.   if ($@) {
  1942.     warn <<"EOM";
  1943. Attempting to test constant code in $ext$modpname/Makefile.PL:
  1944. $generate_code
  1945. __END__
  1946. gave unexpected error $@
  1947. Please report the circumstances of this bug in h2xs version $H2XS_VERSION
  1948. using the perlbug script.
  1949. EOM
  1950.   } else {
  1951.     my $fail;
  1952.  
  1953.     foreach my $file ($constscfname, $constsxsfname) {
  1954.       my $fallback = File::Spec->catfile($fallbackdirname, $file);
  1955.       if (compare($file, $fallback)) {
  1956.         warn << "EOM";
  1957. Files "$ext$modpname/$fallbackdirname/$file" and "$ext$modpname/$file" differ.
  1958. EOM
  1959.         $fail++;
  1960.       }
  1961.     }
  1962.     if ($fail) {
  1963.       warn fill ('','', <<"EOM") . "\n";
  1964. It appears that the code in $ext$modpname/Makefile.PL does not autogenerate
  1965. the files $ext$modpname/$constscfname and $ext$modpname/$constsxsfname
  1966. correctly.
  1967.  
  1968. Please report the circumstances of this bug in h2xs version $H2XS_VERSION
  1969. using the perlbug script.
  1970. EOM
  1971.     } else {
  1972.       unlink $constscfname, $constsxsfname;
  1973.     }
  1974.   }
  1975. }
  1976. close(PL) || die "Can't close $ext$modpname/Makefile.PL: $!\n";
  1977.  
  1978. # Create a simple README since this is a CPAN requirement
  1979. # and it doesnt hurt to have one
  1980. warn "Writing $ext$modpname/README\n";
  1981. open(RM, ">README") || die "Can't create $ext$modpname/README:$!\n";
  1982. my $thisyear = (gmtime)[5] + 1900;
  1983. my $rmhead = "$modpname version $TEMPLATE_VERSION";
  1984. my $rmheadeq = "=" x length($rmhead);
  1985.  
  1986. my $rm_prereq;
  1987.  
  1988. if ( $compat_version < 5.00702 and $new_test )
  1989. {
  1990.    $rm_prereq = 'Test::More';
  1991. }
  1992. else
  1993. {
  1994.    $rm_prereq = 'blah blah blah';
  1995. }
  1996.  
  1997. print RM <<_RMEND_;
  1998. $rmhead
  1999. $rmheadeq
  2000.  
  2001. The README is used to introduce the module and provide instructions on
  2002. how to install the module, any machine dependencies it may have (for
  2003. example C compilers and installed libraries) and any other information
  2004. that should be provided before the module is installed.
  2005.  
  2006. A README file is required for CPAN modules since CPAN extracts the
  2007. README file from a module distribution so that people browsing the
  2008. archive can use it get an idea of the modules uses. It is usually a
  2009. good idea to provide version information here so that people can
  2010. decide whether fixes for the module are worth downloading.
  2011.  
  2012. INSTALLATION
  2013.  
  2014. To install this module type the following:
  2015.  
  2016.    perl Makefile.PL
  2017.    make
  2018.    make test
  2019.    make install
  2020.  
  2021. DEPENDENCIES
  2022.  
  2023. This module requires these other modules and libraries:
  2024.  
  2025.   $rm_prereq
  2026.  
  2027. COPYRIGHT AND LICENCE
  2028.  
  2029. Put the correct copyright and licence information here.
  2030.  
  2031. $licence
  2032.  
  2033. _RMEND_
  2034. close(RM) || die "Can't close $ext$modpname/README: $!\n";
  2035.  
  2036. my $testdir  = "t";
  2037. my $testfile = "$testdir/$modpname.t";
  2038. unless (-d "$testdir") {
  2039.   mkdir "$testdir" or die "Cannot mkdir $testdir: $!\n";
  2040. }
  2041. warn "Writing $ext$modpname/$testfile\n";
  2042. my $tests = @const_names ? 2 : 1;
  2043.  
  2044. open EX, ">$testfile" or die "Can't create $ext$modpname/$testfile: $!\n";
  2045.  
  2046. print EX <<_END_;
  2047. # Before `make install' is performed this script should be runnable with
  2048. # `make test'. After `make install' it should work as `perl $modpname.t'
  2049.  
  2050. #########################
  2051.  
  2052. # change 'tests => $tests' to 'tests => last_test_to_print';
  2053.  
  2054. _END_
  2055.  
  2056. my $test_mod = 'Test::More';
  2057.  
  2058. if ( $old_test or ($compat_version < 5.007 and not $new_test ))
  2059. {
  2060.   my $test_mod = 'Test';
  2061.  
  2062.   print EX <<_END_;
  2063. use Test;
  2064. BEGIN { plan tests => $tests };
  2065. use $module;
  2066. ok(1); # If we made it this far, we're ok.
  2067.  
  2068. _END_
  2069.  
  2070.    if (@const_names) {
  2071.      my $const_names = join " ", @const_names;
  2072.      print EX <<'_END_';
  2073.  
  2074. my $fail;
  2075. foreach my $constname (qw(
  2076. _END_
  2077.  
  2078.      print EX wrap ("\t", "\t", $const_names);
  2079.      print EX (")) {\n");
  2080.  
  2081.      print EX <<_END_;
  2082.   next if (eval "my \\\$a = \$constname; 1");
  2083.   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
  2084.     print "# pass: \$\@";
  2085.   } else {
  2086.     print "# fail: \$\@";
  2087.     \$fail = 1;
  2088.   }
  2089. }
  2090. if (\$fail) {
  2091.   print "not ok 2\\n";
  2092. } else {
  2093.   print "ok 2\\n";
  2094. }
  2095.  
  2096. _END_
  2097.   }
  2098. }
  2099. else
  2100. {
  2101.   print EX <<_END_;
  2102. use Test::More tests => $tests;
  2103. BEGIN { use_ok('$module') };
  2104.  
  2105. _END_
  2106.  
  2107.    if (@const_names) {
  2108.      my $const_names = join " ", @const_names;
  2109.      print EX <<'_END_';
  2110.  
  2111. my $fail = 0;
  2112. foreach my $constname (qw(
  2113. _END_
  2114.  
  2115.      print EX wrap ("\t", "\t", $const_names);
  2116.      print EX (")) {\n");
  2117.  
  2118.      print EX <<_END_;
  2119.   next if (eval "my \\\$a = \$constname; 1");
  2120.   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
  2121.     print "# pass: \$\@";
  2122.   } else {
  2123.     print "# fail: \$\@";
  2124.     \$fail = 1;
  2125.   }
  2126.  
  2127. }
  2128.  
  2129. ok( \$fail == 0 , 'Constants' );
  2130. _END_
  2131.   }
  2132. }
  2133.  
  2134. print EX <<_END_;
  2135. #########################
  2136.  
  2137. # Insert your test code below, the $test_mod module is use()ed here so read
  2138. # its man page ( perldoc $test_mod ) for help writing this test script.
  2139.  
  2140. _END_
  2141.  
  2142. close(EX) || die "Can't close $ext$modpname/$testfile: $!\n";
  2143.  
  2144. unless ($opt_C) {
  2145.   warn "Writing $ext$modpname/Changes\n";
  2146.   $" = ' ';
  2147.   open(EX, ">Changes") || die "Can't create $ext$modpname/Changes: $!\n";
  2148.   @ARGS = map {/[\s\"\'\`\$*?^|&<>\[\]\{\}\(\)]/ ? "'$_'" : $_} @ARGS;
  2149.   print EX <<EOP;
  2150. Revision history for Perl extension $module.
  2151.  
  2152. $TEMPLATE_VERSION  @{[scalar localtime]}
  2153. \t- original version; created by h2xs $H2XS_VERSION with options
  2154. \t\t@ARGS
  2155.  
  2156. EOP
  2157.   close(EX) || die "Can't close $ext$modpname/Changes: $!\n";
  2158. }
  2159.  
  2160. warn "Writing $ext$modpname/MANIFEST\n";
  2161. open(MANI,'>MANIFEST') or die "Can't create MANIFEST: $!";
  2162. my @files = grep { -f } (<*>, <t/*>, <$fallbackdirname/*>, <$modpmdir/*>);
  2163. if (!@files) {
  2164.   eval {opendir(D,'.');};
  2165.   unless ($@) { @files = readdir(D); closedir(D); }
  2166. }
  2167. if (!@files) { @files = map {chomp && $_} `ls`; }
  2168. if ($^O eq 'VMS') {
  2169.   foreach (@files) {
  2170.     # Clip trailing '.' for portability -- non-VMS OSs don't expect it
  2171.     s%\.$%%;
  2172.     # Fix up for case-sensitive file systems
  2173.     s/$modfname/$modfname/i && next;
  2174.     $_ = "\U$_" if $_ eq 'manifest' or $_ eq 'changes';
  2175.     $_ = 'Makefile.PL' if $_ eq 'makefile.pl';
  2176.   }
  2177. }
  2178. print MANI join("\n",@files), "\n";
  2179. close MANI;
  2180.